//   Evernote 操作  Ver 0.10   //
//                             //
//                             //
//   by Atsushi   2010/10/19   //


#previouspage=hidemaruhandle(0);

if (argcount==0)
{
	$word="";
}
else
{
	$word=getarg(0);
}

runex currentmacrodirectory+"\\howdah.exe search "+$word,1,
    0,"" ,4,"" ,1,"" ,4,"" ,2,1,0;
#searchpage=hidemaruhandle(0);

disabledraw;

replaceallfast "^Info: .+\n","",regular;
replaceallfast "^\n","",regular;

gofiletop;
insertfix "(新規作成)\n";
$id[y]="create";

gofiletop;
while (true)
{
	searchdown "\{[0-9a-z\-]+\}",regular;
	if (result==false)
	{
		break;
	}
	
	$id[y]=gettext(foundtopx,foundtopy,foundendx,foundendy);
	
	beginsel;
	moveto foundendx,foundendy;
	delete;
	delete;
	
	selectline;
	replacedown "  (?=\@)","\t  ",regular,inselect;
	golinetop;
	selectline;
	replacedown " (?=\#)","\t  ",regular,inselect;
	escapeinselect;
	escape;
}

gofileend;
insert "\n";
insertfix "≪検索する≫\n";
$id[y]="search";

gofiletop;
config "xTabMode:0x0001";
down;

clearupdated;
enabledraw;
setactivehidemaru #searchpage;

inputpos "ノートを選択してください。";
if (result)
{
	$note=$id[y];
}
else
{
	$note="";
}

setactivehidemaru #previouspage;
closehidemaru #searchpage;

if ($note=="create")
{
	$notename=input("新規ノート名を入力して下さい。","");
	
	if (result)
	{
		runex currentmacrodirectory+"\\howdah.exe create "+$notename,0,
		    0,"" ,0,"" ,0,"" ,4,"" ,2,1,0;
	}
}
else if ($note=="search")
{
	$word=input("検索語を入力して下さい。","");
	
	if (result)
	{
		execmacro currentmacrofilename,$word;
	}
}
else if ($note!="")
{
	runex currentmacrodirectory+"\\howdah.exe edit "+$note,0,
	    0,"" ,0,"" ,0,"" ,4,"" ,2,1,0;
}